Top Lên đầu trang Messenger Hỗ trợ qua Messenger

Phân tích Pareto là một kỹ thuật thống kê áp dụng Nguyên tắc Pareto cho dữ liệu. Điều này thường được gọi là Quy tắc 80:20. Nguyên tắc Pareto dựa trên giả định rằng số lượng đầu vào tương đối nhỏ (20%) có tác động lớn nhất đến kết quả/đầu ra (80%). Quy tắc 80:20 có thể được áp dụng cho nhiều loại dữ liệu ở hầu hết các doanh nghiệp. Ta có 1 số ví dụ như sau:
- 20% sản phẩm nào của doanh nghiệp chiếm 80% doanh thu
- 20% khách hàng nào tạo nên 80% lợi nhuận.
Mặc dù gọi là Quy tắc 80:20 nhưng kết quả thường không đưa ra chính xác theo tỷ lệ 80:20. Quy tắc được đặt tên 80:20 chỉ để bạn dễ nhớ mà thôi. Bất cứ điều gì gần với tỷ lệ này được coi là bình thường. Khi có được kết quả, bạn có thể tập trung nỗ lực kinh doanh vào 20% những việc có ảnh hưởng đến 80% kết quả. (Có thể hiểu là làm ít nhưng được nhiều)
Nguyên tắc Pareto có thể được minh họa bằng biểu đồ Pareto. Trong Power BI, bạn có thể sử dụng biểu đồ cột và đường kết hợp. Cột trong biểu đồ biểu thị các đầu vào riêng lẻ, trong khi biểu đồ dạng đường biểu thị phần trăm tích lũy của các đầu vào khi chúng tăng lên tới 80%.
Để chỉ cho bạn cách xây dựng biểu đồ Pareto trong Power BI, trong bài viết này mình sẽ sử dụng Database của Adventure Works (1 Sample Database của Microsoft) để cho các bạn thấy được 18% sản phẩm của công ty đang đóng góp tới 80% doanh số.

1. Bước 1: Import dữ liệu và thiết lập Data Model

2. Bước 2: Viết Measure để tính toán

a. Tính toán Total Sales

Để tính ra được Total Sales thì bạn chỉ cần sử dụng SUMX như hình dưới đây là được.

POWER BI DAX
Total Sales = SUMX( f_Sales, f_Sales[Order Quantity] * f_Sales[Unit Price] )

b. Tính toán Cumulative %

Đây là 1 Measure khó và cũng hơi dài 1 chút nên mình sẽ Paste Measure lên trước. Sau đó mới giải thích từng đoạn của Measure trên nhé.

POWER BI DAX
Cumulative % = VAR Current_Product_Sales = [Total Sales] VAR All_Product_Sales = CALCULATE( [Total Sales], ALL(d_Product) ) VAR Cumulative_Result = CALCULATE( [Total Sales], FILTER( ALL(d_Product[Product]), [Total Sales] >= Current_Product_Sales ) ) VAR Result = DIVIDE(Cumulative_Result, All_Product_Sales) RETURN IF( NOT ISBLANK([Total Sales]), Result )

Khá dài đúng không? Vì thế hãy đợi chút và đọc phần giải thích ngay dưới đây nhé.
Đầu tiên bạn hãy tạo ra 1 Matrix với Rows là Product, Value thì là Total Sales.
Sau đó hãy sắp xếp cột Total Sales giảm dần.

Về cơ bản cách tính của Pareto như sau.
Đầu tiên bạn cần sắp xếp các giá trị Total Sales theo thứ tự giảm dần.
Sau đó bạn tính cộng dồn từ giá trị đầu tiên đến giá trị hiện tại sau đó chia cho Grand Total để lấy tỷ lệ %.
Ví dụ:
Nếu bạn đang ở Product “Mountain-200 Black, 38” bạn có Total Sales là 4,406,151.3
Lúc này để tính tỷ lệ Cumulative % thì ta sẽ lấy con số trên chia cho Grand Total là 110,336,782.1
Tương tự nếu bạn đang ở dòng của Product “Mountain-200 Black, 42” thì bạn sẽ phải cộng dồn với cả giá trị trước đó nữa tức là 4,406,151.3 + 4,014,067.8 sau đó mới chia cho Grand Total.
Đến đây bạn có vẻ đã biết cách tính rồi. Mình sẽ chuyển sang lý giải công thức DAX ở trên.

POWER BI DAX
VAR Current_Product_Sales = [Total Sales]

Công thức trên sẽ giúp bạn lấy ra được Total Sales của dòng hiện tại theo Filter Context trên bảng Matrix.

POWER BI DAX
VAR All_Product_Sales = CALCULATE( [Total Sales], ALL(d_Product) )

Công thức trên sẽ trả về Total Sales của tất cả các Product (Tạm hiểu đó là Grand Total)

POWER BI DAX
VAR Cumulative_Result = CALCULATE( [Total Sales], FILTER( ALL(d_Product[Product]), [Total Sales] >= Current_Product_Sales ) )

Đây là phần phức tạp nhất của công thức trên.
Bạn có thể tạm hiểu là ta sẽ lặp qua tất cả các dòng trong bảng Product (cột Product) và lấy ra tất cả các Product có giá trị Total Sales >= giá trị Total Sales của dòng hiện tại.
Hiểu đơn giản thì như thế này.
Nếu bạn đang ở Product “Mountain-200 Black, 38” là Product có Sales lớn nhất. Vậy thì tổng cộng dồn lúc này sẽ chỉ là Sales của sản phẩm “Mountain-200 Black, 38” mà thôi.
Vậy nếu ở dòng tiếp theo Product “Mountain-200 Black, 42” thì sao? Khi đó lọc ra sẽ có 2 sản phẩm có Total Sales >= Sales của dòng hiện tại. Khi đó ta sẽ có tổng Sales của dòng số 1 và dòng số 2. Đây chính là Logic để mình hoàn thiện công thức bên trên.

POWER BI DAX
VAR Result = DIVIDE(Cumulative_Result, All_Product_Sales) RETURN IF( NOT ISBLANK([Total Sales]), Result )

Cuối cùng mình chia giá trị cộng dồn cho Grand Total và thu được kết quả mà mình cần.
Các bạn có thể xem kết quả mẫu ở dưới đây.

Tiếp theo ta sẽ tính toán xem là bao nhiêu Product thì đã đạt tới tỷ lệ 80% này.
(Thực ra tỷ lệ có thể du di chứ không nhất thiết phải là 80%)

POWER BI DAX
Count Of Products Making 80% Of Sales = COUNTROWS( FILTER( ADDCOLUMNS( SUMMARIZE( f_Sales, d_Product[Product] ), "Cumulative %", [Cumulative %] ), [Cumulative %] <= 0.8 ) )
POWER BI DAX
% Count Of Products Making 80% of Sales = VAR Total_Products_Make_80_Pct_Of_Sales = [Count Of Products Making 80% Of Sales] VAR All_Products_Have_Sales = CALCULATE( DISTINCTCOUNT(f_Sales[ProductKey]), ALL(f_Sales) ) VAR Result = DIVIDE(Total_Products_Make_80_Pct_Of_Sales, All_Products_Have_Sales) RETURN Result

Bạn sẽ sử dụng 2 Measure trên để tính toán các tỷ lệ này.
Và đây là kết quả:

Bạn có thể thấy là 63 sản phẩm (Chiếm 18% số lượng sản phẩm có phát sinh doanh thu) đã đạt tới mức 80% Sales.
Vậy khi biết điều này thì bạn sẽ làm gì?
Bạn biết được các sản phẩm nào đang chiếm doanh số lớn. Qua đó có thể tập trung nguồn lực của doanh nghiệp để phát triển cũng như đẩy mạnh Sales ở các nhóm sản phẩm này.
Ngoài ra các sản phẩm còn lại không phải là chúng ta sẽ bỏ nó đi ngay mà cần đi sâu vào tìm hiểu xem các sản phẩm này có vấn đề gì mà lại có lượng Sales kém như vậy. Có thể sản phẩm của bạn chưa đủ tốt để cạnh tranh trên thị trường hoặc bạn chưa dồn nguồn lực đủ mạnh để có thể bán nó thôi.
Tiếp theo ta sẽ dựng 1 Pareto Chart trên Power BI như sau.

Đầu tiên bạn hãy chọn biểu đồ Line and clustered column chart.

Margin Pct là 1 Measure mình viết thêm rất đơn giản như sau
Margin Pct = 0.8
Đến đây thì mình đã chia sẻ xong cách viết hàm DAX để tính ra các giá trị và đưa vào biểu đồ Pareto trong Power BI như thế nào.
Các bạn có thể download File Power BI đính kèm theo đường dẫn dưới đây.

📥 Tải xuống file

Các bạn có thể tham khảo 1 video khác về Pareto Chart chi tiết hơn dưới đây



For comment —
please authorize